=FN=

Senhores

Muitas vezes gastamos um tempo tendo que abrir vários programas auxiliares para rodar o Falcon e muitas vezes nos esquecemos de algo e só nos lembramos quando já estamos no 3D.
Pensando nisso criei essa simples bat, mas que ajuda bastante no dia-a-dia.
Basta copiar o script em um arquivo de texto, salvar como "Iniciar_BMS.bat" e executar, ela fecha vários programas que podem consumir recurso computacional e abre os programas auxiliares.

PARA EDITAR precisa abrir em um editor de texto e editar o endereço do programa que deseja abrir ou o nome do programa que deseja fechar. Para comentar a linha basta acrescentar "REM" no inicio.


@echo off
setlocal

echo Fechando programas em background...

REM === Fechar EA App (barra do relógio) ===
taskkill /IM EADesktop.exe /F >nul 2>&1
taskkill /IM EALauncher.exe /F >nul 2>&1

REM === Outros programas ===
taskkill /IM Discord.exe /F >nul 2>&1
taskkill /IM Steam.exe /F >nul 2>&1
taskkill /IM Battle.net.exe /F >nul 2>&1
taskkill /IM PowerToys.exe /F >nul 2>&1
taskkill /IM opera.exe /F >nul 2>&1
taskkill /IM utweb.exe /F >nul 2>&1

timeout /t 1 /nobreak >nul

echo Iniciando ambiente Falcon BMS...

REM =====================================================
REM Função para abrir programa somente se não estiver rodando
REM Uso: call :StartIfNotRunning "Processo.exe" "CaminhoCompleto.exe"
REM =====================================================

goto :MAIN

:StartIfNotRunning
tasklist | find /i "%~1" >nul
if errorlevel 1 (
    echo Iniciando %~1...
    start "" /min "%~2"
) else (
    echo %~1 ja esta em execucao.
)
exit /b

:MAIN

REM === vJoy Config ===
call :StartIfNotRunning "vJoyConfig.exe" "C:\Program Files\vJoy\x64\vJoyConfig.exe"
timeout /t 5 /nobreak >nul

REM === Joystick Gremlin ===
cd /d "C:\Program Files (x86)\H2ik\Joystick Gremlin"
call :StartIfNotRunning "joystick_gremlin.exe" "C:\Program Files (x86)\H2ik\Joystick Gremlin\joystick_gremlin.exe"
timeout /t 3 /nobreak >nul

REM === OpenTrack ===
call :StartIfNotRunning "opentrack.exe" "C:\Program Files (x86)\opentrack\opentrack.exe"
timeout /t 3 /nobreak >nul

REM === FoxVox ===
call :StartIfNotRunning "FoxVox.exe" "C:\Program Files\FoxVox\FoxVox.exe"
timeout /t 3 /nobreak >nul

REM === EZWATCH ===
start "" "C:\Falcon BMS 4.38\Tools\EZBoards-v21\EZWATCH.bat"
timeout /t 2 /nobreak >nul

REM === Falcon BMS ===
call :StartIfNotRunning "FalconBMS_Alternative_Launcher.exe" "C:\Falcon BMS 4.38\Launcher\FalconBMS_Alternative_Launcher.exe"
timeout /t 2 /nobreak >nul

REM === OpenFreq ===
call :StartIfNotRunning "OpenFreq.Client.exe" "C:\Falcon BMS 4.38\Tools\OpenFreq-Client-v1.0.1-win-x64-portable\OpenFreq.Client.exe"

echo.
echo Tudo iniciado!
pause